忘記Windows10產品密鑰不用怕,用這種方法,輕鬆找回密碼

微課傳媒 發佈 2020-04-15T05:05:19+00:00

'Convertbinary to chars Function ConvertToKey Const KeyOffset = 52 Dim isWin8, Maps, i, j, Current, KeyOutput, Last, keypart1, inser



Windows產品密鑰是很重要的一個密碼,它是我們重新安裝激活作業系統時必須要使用的,如果丟失或忘記了Windows產品密鑰,將給我們帶來很大的麻煩。

下面我將提供一個解決方案,你將看到如何使用簡單的VBS腳本來顯示已安裝的Windows 10、Windows 8或Windows 7系統的產品密鑰。這是從電腦上安裝的作業系統中提取產品密鑰的一個非常簡單的解決方案,無需使用任何第三方軟體。

與其它方法相比,這個VBScript解決方案幾乎是完美的,用戶只需要單擊文件即可。



一、創建腳本文件

要查看電腦上安裝的Windows 10產品密鑰,請執行以下操作:

1.打開記事本。

2.將以下文本複製並粘貼到「記事本」窗口中:

Option Explicit  
 
Dim objshell,path,DigitalID, Result  
Set objshell = CreateObject("WScript.Shell") 
'Set registry key path 
Path = "HKLM\SOFTWARE\Microsoft\Windows NT\CurrentVersion\" 
'Registry key value 
DigitalID = objshell.RegRead(Path & "DigitalProductId") 
Dim ProductName,ProductID,ProductKey,ProductData 
'Get ProductName, ProductID, ProductKey 
ProductName = "Product Name: " & objshell.RegRead(Path & "ProductName") 
ProductID = "Product ID: " & objshell.RegRead(Path & "ProductID") 
ProductKey = "Installed Key: " & ConvertToKey(DigitalID)  
ProductData = ProductName  & vbNewLine & ProductID  & vbNewLine & ProductKey 
'Show messbox if save to a file  
If vbYes = MsgBox(ProductData  & vblf & vblf & "Save to a file?", vbYesNo + vbQuestion, "BackUp Windows Key Information") then 
   Save ProductData  
End If 
 
 
 
'Convert binary to chars 
Function ConvertToKey(Key) 
    Const KeyOffset = 52 
    Dim isWin8, Maps, i, j, Current, KeyOutput, Last, keypart1, insert 
    'Check if OS is Windows 8 
    isWin8 = (Key(66) \ 6) And 1 
    Key(66) = (Key(66) And &HF7) Or ((isWin8 And 2) * 4) 
    i = 24 
    Maps = "BCDFGHJKMPQRTVWXY2346789" 
    Do 
           Current= 0 
        j = 14 
        Do 
           Current = Current* 256 
           Current = Key(j + KeyOffset) + Current 
           Key(j + KeyOffset) = (Current \ 24) 
           Current=Current Mod 24 
            j = j -1 
        Loop While j >= 0 
        i = i -1 
        KeyOutput = Mid(Maps,Current+ 1, 1) & KeyOutput 
        Last = Current 
    Loop While i >= 0  
     
    If (isWin8 = 1) Then 
        keypart1 = Mid(KeyOutput, 2, Last) 
        insert = "N" 
        KeyOutput = Replace(KeyOutput, keypart1, keypart1 & insert, 2, 1, 0) 
        If Last = 0 Then KeyOutput = insert & KeyOutput 
    End If     
     
 
    ConvertToKey = Mid(KeyOutput, 1, 5) & "-" & Mid(KeyOutput, 6, 5) & "-" & Mid(KeyOutput, 11, 5) & "-" & Mid(KeyOutput, 16, 5) & "-" & Mid(KeyOutput, 21, 5) 
    
     
End Function 
'Save data to a file 
Function Save(Data) 
    Dim fso, fName, txt,objshell,UserName 
    Set objshell = CreateObject("wscript.shell") 
    'Get current user name  
    UserName = objshell.ExpandEnvironmentStrings("%UserName%")  
    'Create a text file on desktop  
    fName = "C:\Users\" & UserName & "\Desktop\WindowsKeyInfo.txt" 
    Set fso = CreateObject("Scripting.FileSystemObject") 
    Set txt = fso.CreateTextFile(fName) 
    txt.Writeline Data 
    txt.Close 
End Function 

3.單擊「文件-另存為」命令,在「保存類型」中選擇「所有文件」,在「文件名」中將上面的文本保存到桌面上帶有「 .vbs」擴展名的文件中,文件名可以自己隨意命名。


提示:為確保正確保存擴展名為「 .vbs」的文件,可以鍵入文件名並用雙引號引起來,例如「BackupWindowsKey.vbs」。

二、查看/備份Windows10產品密鑰

現在打開BackupWindowsKey.vbs文件,瞧,Windows10產品密鑰會顯示在螢幕上!把它記錄下來,保存到一個安全的地方。


如果你想直接下載得到BackupWindowsKey.vbs文件,請關注我,然後私信「密鑰腳本」。

我在Windows 7、Windows 8和Windows 10上測試了該技巧,它在所有提到的作業系統中均能完美運行。

擴展閱讀:

■>>恢復win10登錄密碼的9大工具,一個比一個強大,維修電腦必備

■>>在Windows 10中管理用戶帳戶和密碼

■>>如何重置忘記的Windows10密碼,掌握這3個技巧就行了

■>>永久刪除桌面上激活Windows10水印,電腦高手都在用的技巧

更多windows 10作業系統使用技巧,請關注→→#win10玩機技巧#

想了解更多精彩內容,快來關注@微課傳媒



1.頭條號【微課傳媒】專注軟體分享,如果你喜歡玩軟體,歡迎關注、評論、收藏、轉發。

2.在學習中有什麼問題,歡迎與我溝通交流,今日頭條號搜索【微課傳媒】,我在這裡等你喲!

關鍵字: